;noesyi4pr3d
;MANUFACTURER: Bruker
;MODEL: DMX
;AUTHOR: Charles G. Hoogstraten
;DESCRIPTION: avance-version
;BMRB Pulse Sequence Accession Number: 2
;3D sequence with
;   homonuclear correlation via dipolar coupling 
;   dipolar coupling may be due to noe or chemical exchange.
;   H-1/X correlation via heteronuclear zero and double quantum
;      coherence 
;phase sensitive using TPPI
;with decoupling during acquisition
;with presaturation during relaxation delay and mixing time
;mod to states-tppi cgh 1/5/95
;mod to BD-NOESY with gradients cgh 1/6/95

#include <Avance.incl>
#include <Grad.incl>


p2=p1*2
p4=p3*2
;;d2=1s/(cnst2*2)
d11=30m
d13=3u


1 d11 ze
2 d11 do:f2
3 d11
6 d11
7 d11
4 4u
  d1 pl2:f2 
;  d12 pl9:f1
;  d1 cw:f1
;  d13 do:f1
;  d12 pl1:f1
  p1 ph3
  d0
  p4:f2 ph0
  d0
  p1 ph0
;  GRADIENT(cnst21)
  d8
  p1 ph0
  GRADIENT(cnst22)      
  d4 pl2:f2              ;d4=2.3 ms - length of grads 2, 5
  (p4 ph0):f2 (p2 ph0)
  GRADIENT(cnst22)
  d4
  p8 ph0                ;p8=1.0ms
  d13
  p1 ph1
  GRADIENT(cnst23)
  d9                      ;settling time
  (p3 ph4):f2
  d10
  p2 ph0
  d10
  p3:f2 ph0
  GRADIENT(cnst24)        ;cnst24<0
  d9
  p1 ph0
  GRADIENT(cnst25)        ;cnst25<0
  d4
  (p2 ph0) (p4 ph0):f2
  GRADIENT(cnst25)
  d4 pl12:f2
  p8*1.5 ph0
  d13
  go=2 ph31 cpd2:f2
  d11 do:f2 wr #0 if #0 ip3 zd 
  lo to 3 times 2
  d11 id0 ip31*2
  lo to 6 times l6
  d11 rd0 ip4 
  lo to 7 times 2
  d11 id10 ip31*2
  lo to 4 times l4
exit


ph0=0
ph1=1
ph2=2
ph3=0 2
ph4=0 0 2 2
ph31=0 2 2 0


;pl1 : f1 channel - power level for pulse (default)
;pl2 : f2 channel - power level for pulse (default)
;pl9 : f1 channel - power level for presaturation
;pl12: f2 channel - power level for CPD/BB decoupling
;p1 : f1 channel -  90 degree high power pulse
;p2 : f1 channel - 180 degree high power pulse
;p3 : f2 channel -  90 degree high power pulse
;p4 : f2 channel - 180 degree high power pulse
;p31:  - 90 degree pulse for decoupling sequence
;d0 : incremented delay (F1 in 3D)                     [3 usec]
;d1 : relaxation delay; 1-5 * T1
;d2 : 1/((2J)XH)
;d8 : mixing time
;d10: incremented delay (F2 in 3D)                     [3 usec]
;d11: delay for disk I/O                             [30 msec]
;d12: delay for power switching                      [20 usec]
;d13: short delay                                    [3 usec]
;in0: 1/(4 * SW(H)) = (1/2) DW(H)
;nd0: 4
;in10: 1/(4 * SW(X)) = (1/2) DW(X)
;nd10: 4
;NS: 4 * n
;DS: 32
;td1: number of experiments in F1
;td2: number of experiments in F2
;MC2: TPPI in F1
;MC2: TPPI in F2
;cpd2: decoupling according to sequence defined by cpdprg2